Get an Avergae and Total from the Time Collected

taking your previous sample data, this is the way you'd get the average, and the sum is gotten simply by changing AVG to SUM

    DECLARE @YourTable TABLE (StartTime int,  EndTime int)

    INSERT  INTO @YourTable SELECT  70500, 71002
    INSERT  INTO @YourTable SELECT  120501, 121845


    Select CONVERT(CHAR(8), DATEADD(SECOND, AVG(DATEDIFF(SECOND,
          CONVERT(DATETIME,CONVERT(VarCHAR(02),Starttime/10000)+':'
         +CONVERT(VARCHAR(02),(StartTiME/100)%100)+':'
         +CONVERT(VARCHAR(02),StartTime%100),8),
          CONVERT(DATETIME,CONVERT(VarCHAR(02),Endtime/10000)+':'
         +CONVERT(VARCHAR(02),(EndTime/100)%100)+':'
          +CONVERT(VARCHAR(02),EndTime%100),8))),
       CONVERT(DATETIME, '00:00:00', 113)),8)                   
     AS ElapsedTime
    FROM    @YourTable 

This is an example of using aggregate function on sets of data that you can hopefully use to apply the same logic to your dataset

USE [AdventureWorks]
GO
-- all details, no aggregation
SELECT [sod].[SalesOrderID] ,
    [sod].[OrderQty] ,
    [sod].[UnitPrice] ,
    [sod].[LineTotal]
FROM [Sales].[SalesOrderDetail] AS sod
WHERE [sod].[SalesOrderID] BETWEEN 43659 AND 43670

-- using SUM and AVG aggregation functions
SELECT [sod].[SalesOrderID] ,
    AVG([sod].[OrderQty]) AS [Average quantity] ,
    AVG([sod].[UnitPrice]) AS [Average price],
    SUM([sod].[LineTotal]) AS [Total Cost]
FROM [Sales].[SalesOrderDetail] AS sod
WHERE [sod].[SalesOrderID] BETWEEN 43659 AND 43670
GROUP BY [sod].[SalesOrderID]

here is an example that works with time data

IF OBJECT_ID('Times') IS NOT NULL 
    DROP TABLE [dbo].[Times]
    GO
    -- create an example table
CREATE TABLE Times
    (
      itemID INT ,
      dtStart DATETIME ,
      dtEnd DATETIME
    )
GO
-- add 100 rows
WHILE ( SELECT COUNT(*)
         FROM [dbo].[Times]
      ) < 100 
    BEGIN
       INSERT [dbo].[Times]
          ( itemID ,
            [dtStart] 
          )
          SELECT ABS(CHECKSUM(NEWID())) % 7 + 1 AS [itemid] ,
                 DATEADD(s, ABS(CHECKSUM(NEWID())) % 1000 + 1,
                    '20120428') AS dtastart
    END
    GO

-- add end times - a random number of seconds after the start time
UPDATE [dbo].[Times]
    SET    [dtEnd] = DATEADD(s, ABS(CHECKSUM(NEWID())) % 1000 + 1, [t].dtstart)
    FROM [dbo].[Times] AS t
go
-- show data
SELECT [dbo].[Times].[itemID] ,
       [dbo].[Times].[dtStart] ,
       [dbo].[Times].[dtEnd] ,
       DATEDIFF(s, [dbo].[Times].[dtStart], [dbo].[Times].[dtEnd]) AS [duration]
    FROM times
    ORDER BY [dbo].[Times].[itemID] ,
       duration
go
-- show aggregated data
SELECT [dbo].[Times].[itemID] ,
       AVG(DATEDIFF(s, [dbo].[Times].[dtStart], [dbo].[Times].[dtEnd])) AS [avg_duration] ,
       SUM(DATEDIFF(s, [dbo].[Times].[dtStart], [dbo].[Times].[dtEnd])) AS [sum_duration]
    FROM times
    GROUP BY [dbo].[Times].[itemID]

you will need to consider whether to use seconds (as I have) or whether minutes or hours or even milliseconds are more useful for you.