Must a transaction be contained in a TRY...CATCH block?

Yes, you can. Just make sure that you check for @@trancount before attempting to rollback transaction in the catch block. Here is the sample:

use AdventureWorks;
go

set nocount on;

declare @msg varchar(max);
declare @i int;

begin tran;

begin try

    delete dbo.DatabaseLog

    set @msg = cast(@@rowcount as varchar(10)) + ' records have been deleted.'

    -- force the flow to bail out to the catch block before the damage is done
    set @i = 1 / 0;

    commit tran;

end try

begin catch

    if @@trancount > 0 rollback tran;

    set 
        @msg = 'Error # ' + cast(error_number() as varchar(10)) + 
        ' occured on line ' + cast(error_line() as varchar(10)) + 
        '. Error message: ' + error_message(); 

end catch;

select @msg result;

-- sanity check (to make sure the records are still there
select * from dbo.DatabaseLog;

set nocount off;
go

The above will produce something like this in the results window:

result
--------------------------------------------------------------------------------
Error # 8134 occured on line 15. Error message: Divide by zero error encountered.

The transaction is rolled back due to the above error.

Oleg

Works like a charm.

Try it out...

USE tempdb ;

BEGIN TRAN ;

BEGIN TRY
    SELECT
        *
    FROM
        sys.columns ;
    -- oh, no! our query failed...
    RAISERROR('gotcha', 25, 1) ;
    COMMIT ;
END TRY
BEGIN CATCH
    SELECT
        *
    FROM
        sys.tables ;
    ROLLBACK ;
END CATCH

I dont think that syntax would be supported. Try it on a test environment and see if it works.

What are you trying to achieve? I cant think of a reason you would want to do this. The TRY is where the data update is attempted and then the CATCH is where you handle any issues encountered with completing the data change.