SQL 2008 Table Partitioning

Question

Hello,

I am using Table Partitioning in SQL 2008, I created a partitioned function right boundary, a partitioned scheme and a partitioning column (datetime) in a way that I have 12 partitions and 13 filegroups (12 for each month of the year and 1 additional filegroup).

Is there a way to create a script that I can run once a year that creates 12 new partitions on 12 new filegroups and set the boundary for each partition as a new month for a new year? i.e. create 12 new partitions per year

Regards,

Joe

Answer 1

This isn't going to be exactly what you want, but it will certainly get you started:

DECLARE @path [varchar](255)
SET @path = 'D:\Database_Data\'
-- Loop from 1 to 12
DECLARE @x int
SET @x = 1
WHILE @x <= 12
BEGIN

  DECLARE @newdate [datetime], @newDateString [varchar](10)
  SET @newdate = DATEADD(m, @x, GETDATE())
  SET @newDateString = CONVERT([varchar], YEAR(@newDate)) + RIGHT('00' + CONVERT([varchar], MONTH(@newDate)), 2)  

    -- create filegroup
    PRINT 'ALTER DATABASE [' + DB_NAME() + '] ADD FILEGROUP [PARTITION_DATA_' + @newDateString + ']'  
  PRINT 'GO'
  -- create file in filegroup
  PRINT 'ALTER DATABASE [' + DB_NAME() + '] ADD FILE ('
  PRINT '    NAME = ''PARTITION_DATA_' + @newDateString + ','
  PRINT '    FILENAME = ''' + @path + db_name() + '_PARTITION_DATA_' + @newDateString + '.ndf'')'
  PRINT 'TO FILEGROUP [PARTITION_DATA_' + @newDateString + ']'
  PRINT 'GO'
  -- SET NEXT USED for partition scheme
  PRINT 'ALTER PARTITION SCHEME [MonthPartitions] NEXT USED [PARTITION_DATA_' + @newDateString + ']'
  PRINT 'GO'
  -- Now add boundary value to partition function
  PRINT 'ALTER PARTITION FUNCTION [MonthPartitionFunction] SPLIT RANGE ( ''' + CONVERT([varchar], YEAR(@newDate)) + '/' +  RIGHT('00' + CONVERT([varchar], MONTH(@newDate)), 2) + '/01'' )'
  PRINT 'GO'
    SET @x = @x + 1
END

SQL 2008 Table Partitioning

Follow this question

Related Questions